// Super Shotgun (Doom II)

ACTOR IDMSuperShotgun : IDMWeapon
{
	Weapon.SelectionOrder 400
	Weapon.SlotNumber 3
	Weapon.Sisterweapon "SuperShotgunLevel2"
	Weapon.PreferredSkin "SSGMarine"
	Weapon.AmmoUse 2
	Weapon.AmmoGive 10
	Weapon.AmmoType "IDMShell"
	Weapon.Kickback 200
	Inventory.PickupMessage "Super Shotgun!"
	Obituary "%o was splattered by %k's Super Shotgun."
	Tag "Super Shotgun"
	Decal BulletChip
	Damagetype "Bullet"
	AttackSound "weapons/sshotf"
	States
	{
	Ready:
	  SHT2 A 1 A_WeaponReady
      Loop
	Deselect:
      SHT2 A 0 A_Lower
      SHT2 A 0 A_Lower
	  SHT2 A 1 A_Lower
      Loop
	Select:
	  TNT1 A 0 A_PlaySound("weapons/wswitch",CHAN_WEAPON)
	Sloop:
      SHT2 A 0 A_Raise
      SHT2 A 0 A_Raise
      SHT2 A 1 A_Raise
      Loop
	Fire:
	  SHT2 A 3
	  SHT2 A 0 A_JumpIfInventory("PowerQuadDamage", 1, "Quad")
	Normal:
	  SHT2 A 0 A_GunFlash
      SHT2 A 7 Bright A_FireBullets(11.2, 7.1, 50, 5, "IDMBulletPuff")
	  Goto FireEnd
	Quad:
	  TNT1 A 0 A_Playsound("misc/qdmg",CHAN_AUTO,1)
      SHT2 A 0 A_GunFlash
	  SHT2 A 7 Bright A_FireBullets(11.2, 7.1, 50, 5, "ExtremePuff")
	FireEnd:
      SHT2 B 7
      SHT2 C 7 A_CheckReload
      SHT2 D 7 A_OpenShotgun2
      SHT2 E 7
      SHT2 F 7 A_LoadShotgun2
      SHT2 G 6
      SHT2 H 6 A_CloseShotgun2
      SHT2 A 5 A_ReFire
      Goto Ready
	Flash:
      SHT2 J 4 Bright A_Light2
      SHT2 I 2 Bright A_Light1
      Goto LightDone
	Spawn:
      SGN2 A -1 Bright
      Stop
	}
}

ACTOR SuperShotgunLevel2 : IDMSuperShotgun
{
  Weapon.Sisterweapon "IDMSuperShotgun"
  +POWERED_UP
  States
  {
  Ready:
    SHT3 A 1 A_WeaponReady
    Loop
  Deselect:
    SHT3 A 0 A_Lower
    SHT3 A 0 A_Lower
	SHT3 A 1 A_Lower
    Loop
  Select:
	TNT1 A 0 A_PlaySound("weapons/wswitch",CHAN_WEAPON)
  Sloop:
    SHT3 A 0 A_Raise
    SHT3 A 0 A_Raise
    SHT3 A 1 A_Raise
    Loop
  Fire:
	SHT3 A 3
	SHT3 A 0 A_JumpIfInventory("PowerQuadDamage", 1, "Quad")
  Normal:
	SHT3 A 0 A_GunFlash
    SHT3 A 7 Bright A_FireBullets(11.2, 7.1, 150, 5, "IDMBulletPuff")
	Goto FireEnd
  Quad:
	TNT1 A 0 A_Playsound("misc/qdmg",CHAN_AUTO,1)
	SHT3 A 0 A_GunFlash
	SHT3 A 7 Bright A_FireBullets(11.2, 7.1, 150, 5, "ExtremePuff")
	Goto FireEnd
  FireEnd:
    SHT3 B 7
    SHT3 C 7 A_CheckReload
    SHT3 D 7 A_OpenShotgun2
    SHT3 E 7
    SHT3 F 7 A_LoadShotgun2
    SHT3 G 6
    SHT3 H 6 A_CloseShotgun2
    SHT3 A 5 A_ReFire
    Goto Ready
  Flash:
    SHT3 J 4 Bright A_Light1
    SHT3 I 2 Bright A_Light2
    Goto LightDone
  }
}

ACTOR BuckShotSuperShotgun : IDMSuperShotgun replaces SuperShotgun // Super Shotgun for the Buckshot modifier
{
	Weapon.AmmoUse 0
	Weapon.AmmoType None
	+WEAPON.NOLMS
}